Rules best approach

[Dick60]

What is the best way to handle my problem: I have 4 switches and a led indicator. If mindestens one of the 4 switches is active, the led must be turned on untill all switches are inactive. Because there is a limitation on both the

AND

and

IF

option, I see no solution for me to solve this problem.

[Ath]

Code: Select all

on checkSwitches do
  if [Switch1#State]=0 or [Switch3#State]=0 or [Switch3#State]=0 or [Switch4#State]=0
    GPIO,4,0 // Turn on LED
  else
    GPIO,4,1 // Turn off LED
  endif
endon

[Dick60]

Question, the name

on checkSwitches do

is one you gave. I used always the name of a switch like

on Switch1#State do

but that is not mandatory? I can use any name?

[Ath]

I can use any name?

You can define event handlers (rules) as you like, there are some events generated by ESPEasy, like Switch#State when a value of a task changes, but you can also 'generate' an event yourself using the Event or AsyncEvent (preferred) command:

Code: Select all

On Switch1#State do
  // regular commands for this switch
  AsyncEvent,checkSwitches // Update LED state next
Endon

On Switch2#State do
  // regular commands for this switch
  AsyncEvent,checkSwitches // Update LED state next
Endon

// Add for other switches similarly

AsyncEvent will add it to the the list of events to handle, while Event will execute it immediately, possibly delaying the response to the switch changing its state, and using more memory, that's why AsyncEvent is preferred.

[Dick60]

It looked that easy but in practice it is another story. I ave installed the latest firmware on my ESP32. I have some push switches and some relays. The pushswitches activate the relay using the rules option. All works fine. If one of the switches is active, a led need to be activated as in indication one of the relays are active. I keep it simple to start with one active relay with this script but that does not work for me. Port 16 is not changing and even the Event is not started. The status of the Stekkerdoos_houtST1 is changing to ! but nothing happens with GPIO 16.

Code: Select all

on checkSwitches do
  if [Stekkerdoos_houtST1#State]=1
    GPIO,16,0 // Turn on LED
        Else
    GPIO,16,1
      endif
Endon   

[TD-er]

Is the event checkSwitches fired?
You should see it occur in the logs.
Or you could add something like this in the event block for debugging:

Code: Select all

on checkSwitches do
  LogEntry,"checkSwitches: current state: [Stekkerdoos_houtST1#State]"
  if [Stekkerdoos_houtST1#State]=1
    GPIO,16,0 // Turn on LED
  Else
    GPIO,16,1
  endif
Endon   

[Dick60]

No it is not fired. After activating/deactivating the Relay I only get this in my log or tu :
HTTP: GPIO,33,1
6921458: GPIO : port#33: set to 1
6921543: SW : GPIO=33 State=1 Output value=0
6921573: EVENT: Stekkerdoos_houtST1#State=0
or this one
7043752: HTTP: GPIO,33,0
7043757: GPIO : port#33: set to 0
7043887: SW : GPIO=33 State=0 Output value=1
7043919: EVENT: Stekkerdoos_houtST1#State=1

[chromo23]

Can you post all your rules?

[Dick60]

This is fired. Push button activates the Relay:

Code: Select all

on Stekkerdoos_houtSW1#State do
If [Stekkerdoos_houtSW1#State]=0 and [Stekkerdoos_houtRestart#State]=0
GPIO,33,0
else
GPIO,33,1
endif
endon

This one is during Reboot to prevent unnecessary switching:

Code: Select all

On System#Boot do
GPIO,4,1 //prevent activating GPIO's during reboot
GPIO,13,1
GPIO,33,1
TimerSet,1,10
endon

On rules#Timer=1 do
GPIO,4,0 
endon

[chromo23]

But this can´t be all your rules...

Where is this part:

Code: Select all

AsyncEvent,checkSwitches

[Dick60]

this is it so probably I miss something. Now reading more carefully ATH suggested but I thought it was a nice to have but it is manditory i assume.

[chromo23]

this is it so probably I miss somthing

You do...

To fire this:

Code: Select all

On checkSwitches Do
  LogEntry,"checkSwitches: current state: [Stekkerdoos_houtST1#State]"
  If [Stekkerdoos_houtST1#State]=1
    GPIO,16,0 // Turn on LED
  Else
    GPIO,16,1
  Endif
Endon  

You need to call following somewhere in another rules block :

Code: Select all

AsyncEvent,checkSwitches

Like @Ath already suggested:

I can use any name?

You can define event handlers (rules) as you like, there are some events generated by ESPEasy, like Switch#State when a value of a task changes, but you can also 'generate' an event yourself using the Event or AsyncEvent (preferred) command:

Code: Select all

On Switch1#State do
  // regular commands for this switch
  AsyncEvent,checkSwitches // Update LED state next
Endon

On Switch2#State do
  // regular commands for this switch
  AsyncEvent,checkSwitches // Update LED state next
Endon

// Add for other switches similarly

AsyncEvent will add it to the the list of events to handle, while Event will execute it immediately, possibly delaying the response to the switch changing its state, and using more memory, that's why AsyncEvent is preferred.

So your Rules would look like this:

Code: Select all

on Stekkerdoos_houtSW1#State do
 AsyncEvent,checkSwitches
 If [Stekkerdoos_houtSW1#State]=0 and [Stekkerdoos_houtRestart#State]=0
  GPIO,33,0
 else
  GPIO,33,1
endif
endon

on checkSwitches do
  LogEntry,"checkSwitches: current state: [Stekkerdoos_houtST1#State]"
  if [Stekkerdoos_houtST1#State]=1
    GPIO,16,0 // Turn on LED
  Else
    GPIO,16,1
  endif
Endon  

[chromo23]

I also recommend this wonderful documentation:
https://espeasy.readthedocs.io/en/lates ... ight=event

[Dick60]

This works perfectly, now I try to understand what is happening and implement it also for the other 3 switches. Thanks for now.

[Dick60]

I hoped that this would work using 2 switches but changing sw1 or sw2 will turn On the led because st1 or st2 or both changed the status but I want to keep the led on untill all ST1 AND ST2 are off. This is what I thought:

Code: Select all

on Stekkerdoos_houtSW1#State do
 AsyncEvent,checkSwitches
 If [Stekkerdoos_houtSW1#State]=0
  GPIO,33,0
 else
  GPIO,33,1
endif
endon

on Stekkerdoos_houtSW2#State do
 AsyncEvent,checkSwitches
 If [Stekkerdoos_houtSW2#State]=0
  GPIO,22,0
 else
  GPIO,22,1
endif
endon

Code: Select all

on checkSwitches do
  LogEntry,"checkSwitches: current state: [ST1 Or ST2]"
  if [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1
    GPIO,16,1 // Turn on LED
  Elseif [Stekkerdoos_houtST1#State]=0 and [Stekkerdoos_houtST2#State]=0
    GPIO,16,0
  endif
Endon  

[Ath]

A few questions:
- Why are you checking 2 switches to turn an output on or off? New requirement?

Code: Select all

If [Stekkerdoos_houtSW1#State]=0 and [Stekkerdoos_houtRestart#State]=0 // check 2 switches????

- Why have you changed the rather simple, basic structure of checkSwitches?

Code: Select all

  if [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1
    GPIO,16,1 // Turn on LED
  Elseif [Stekkerdoos_houtST1#State]=0 and [Stekkerdoos_houtST2#State]=0

All you had to do there is change the names of the switches, so it should en up something like this:

Code: Select all

On checkSwitches Do
  LogEntry,"checkSwitches: current state: ST1=[Stekkerdoos_houtST1#State], ST2=[Stekkerdoos_houtST2#State]" // etc.
  If [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1 // Add more on-state switches like this, using the 'or' condition, when needed
    GPIO,16,0 // Turn on LED
  Else
    GPIO,16,1
  Endif
Endon

[Dick60]

This is what I have for now:

Code: Select all

on Stekkerdoos_houtSW1#State do
 AsyncEvent,checkSwitches
 If [Stekkerdoos_houtSW1#State]=0
  GPIO,33,0
 else
  GPIO,33,1
endif
endon

on Stekkerdoos_houtSW2#State do
 AsyncEvent,checkSwitches
 If [Stekkerdoos_houtSW2#State]=0
  GPIO,22,0
 else
  GPIO,22,1
endif
endon


on checkSwitches do
  LogEntry,"checkSwitches: current state: [ST1 Or ST2]"
  if [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1
    GPIO,16,1 // Turn on LED
    Else
    //Elseif [Stekkerdoos_houtST1#State]=0 and [Stekkerdoos_houtST2#State]=0
    GPIO,16,0
  endif
Endon  

Led is turned on and off for Stekkerdoos_houtSW1#State. The same for Stekkerdoos_houtSW2#State but if you use Stekkerdoos_houtSW1#State (led on) and after that use Stekkerdoos_houtSW2#State the led is turned off and I would expect that the led keeps on.

[chromo23]

but if you use Stekkerdoos_houtSW1#State (led on) and after that use Stekkerdoos_houtSW2#State the led is turned off and I would expect that the led keeps on.

What do you mean? Could you use the actual states when describing what you want?
Describing Stekkerdoos_houtSW1#State with "led on" doesn't say anything about the actual state because the led could be on because Stekkerdoos_houtSW2#State=1

Edit: i also see no reason why your rules shouldn´t work as expected

[Dick60]

The project is a 220v switchboard with 4 push switches (Sw1-SW4/ for manual switching the status of the relais (ST1-ST4). If one of the relais (ST1-ST4) has the status 1 (ON) a led must turn on as an indicator that one of the relais is still active. As soon as al the relais are 0 (OFF), the led is turned off. This is what I wanted to establish but is more difficult than expected.

[chromo23]

Maybe @Ath gave you a hint (by accident or on purpose) with this:

All you had to do there is change the names of the switches, so it should en up something like this:

Code: Select all

On checkSwitches Do
  LogEntry,"checkSwitches: current state: ST1=[Stekkerdoos_houtST1#State], ST2=[Stekkerdoos_houtST2#State]" // etc.
  If [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1 // Add more on-state switches like this, using the 'or' condition, when needed
    GPIO,16,0 // Turn on LED
  Else
    GPIO,16,1
  Endif
Endon

As you can see he changed the states for the GPIO 16.
So maybe your Led is inverted and therefore doesn´t respond as you expect...

[chromo23]

One last question:
If [Stekkerdoos_houtST1#State] is generated by a push button how does this work:

Code: Select all

If [Stekkerdoos_houtSW1#State]=0
  GPIO,33,0
 else
  GPIO,33,1
endif

The relay would only turn on as long as the push button is pressed.
For your led rule, you should monitor the state of the relays (or better the GPIOSs of the relays) instead of the buttons.

Edit: Or maybe i interpret push switches wrong, for me they are the same than push buttons

[Ath]

Maybe @Ath gave you a hint (by accident or on purpose) with this:

Well, as ESP's can't deliver much current on a high output (few mA only) but do allow to draw around 20 mA when in low state, I usually have the GPIO on 0 for an On state. So that's no accident

[Dick60]

The Push button is defined in my project as a PUSH BUTTON ACTIVE HIGH so monitoring the trigger on the button is possible in my opinion. but it result in
sw(itch)1 actvite st(ekker)1 turns on the led (sw2 and st1 both inactive.
sw(itch) 2 active st(ekker)2 turns on but turn off the led even st1 is active. I expected the led keeps on because both or one of the ST are still active.
It is difficult to explain. I hope this makes the problem clear

[chromo23]

Can you post the log when this happens:

sw(itch) 2 active st(ekker)2 turns on but turn off the led even st1 is active.

[Dick60]

Push SW1(gpio13) resulting activate ST1(gpio33) and turn on the LED(gpio16).

SW : GPIO=13 State=1 Output value=0
EVENT: Stekkerdoos_houtSW1#State=0
ACT : GPIO,33,0
GPIO : port#33: set to 0
ACT : AsyncEvent,checkSwitches
EVENT: checkSwitches
ACT : LogEntry,'checkSwitches: current state: [ST1 Or ST2]'
checkSwitches: current state: [ST1 Or ST2]
ACT : GPIO,16,0
GPIO : port#16: set to 0
ACT : Endon
Command unknown: Endon
SW : GPIO=33 State=0 Output value=1
SW : GPIO=16 State=0 Output value=0
EVENT: Stekkerdoos_houtST1#State=1
EVENT: Stekkerdoos_houtLed#State=0


Push SW2(gpio17) resulting activate ST2(gpio22) bt turn off LED(gpio16)-

SW : GPIO=17 State=1 Output value=0
EVENT: Stekkerdoos_houtSW2#State=0
ACT : GPIO,22,0
GPIO : port#22: set to 0
ACT : AsyncEvent,checkSwitches
EVENT: checkSwitches
ACT : LogEntry,'checkSwitches: current state: [ST1 Or ST2]'
checkSwitches: current state: [ST1 Or ST2]
ACT : GPIO,16,1
GPIO : port#16: set to 1
ACT : Endon
Command unknown: Endon
SW : GPIO=22 State=0 Output value=1
SW : GPIO=16 State=1 Output value=1
EVENT: Stekkerdoos_houtST2#State=1
EVENT: Stekkerdoos_houtLed#State=1

Both SW1 and 2 are activated, the LED is NOT on, deactivating SW1 and 2 will not change the status of the LED.

[chromo23]

ACT : Endon
Command unknown: Endon

It seems you made some mistake in your rules, cause this shouldn´t happen and is probably the cause, that leads to unexpected behavior....
Can you please post all of your rules? Otherwise it is impossible to analyze this.

Another thing:

ACT : LogEntry,'checkSwitches: current state: [ST1 Or ST2]'

It is probably not necessary anymore once the Endon issue is corrected but originally i wanted to see what the switch states in the log say and your LogEntry is useless for that.
You should change it to the following as @Ath suggested:

Code: Select all

LogEntry,"checkSwitches: current state: ST1=[Stekkerdoos_houtST1#State], ST2=[Stekkerdoos_houtST2#State]" // etc.

It is easier to see what the states are when the event checkSwitches is fired...

Edit: you can also check your rules by yourself:
1. Make sure every command is in a event block
2. every event block begins with "on....do" and ends with "endon"
3. every "if" statement is closed with "endif"

[chromo23]

Ok.. your naming of switches an relays is confusing me a bit.

You do seem to check the relay states and not the switch state in "checkSwitches":

Code: Select all

if [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1

But the state of the relays is changed after "AsyncEvent,checkSwitches" (as you can see in your log output)
So it is better to put this at the end of the "switch" event blocks like this:

Code: Select all

On Stekkerdoos_houtSW1#State Do
 If [Stekkerdoos_houtSW1#State]=0
  GPIO,33,0
 Else
  GPIO,33,1
 Endif
 AsyncEvent,checkSwitches
Endon

As you can see in the image. The "checkSwitches" event needs to be processed after "EVENT: Stekkerdoos_houtST2#State=1" otherwise it is useless.

events.png (113.38 KiB) Viewed 4272 times

So keep an eye on log output while investigating your code it is really helpful

Edit: To be really sure the "checkSwitches" event is fired at the right time you could use a new event block like this:

Code: Select all

On Stekkerdoos_houtST1#State Do
 AsyncEvent,checkSwitches
Endon

[Dick60]

Sorry, I forgot to mention that the log was the result of the adjusted script I changed already. So the result of the log is from this script:

Code: Select all

on Stekkerdoos_houtSW1#State do
 If [Stekkerdoos_houtSW1#State]=0
  GPIO,33,0
 else
  GPIO,33,1
endif
AsyncEvent,checkSwitches
endon

on Stekkerdoos_houtSW2#State do
  If [Stekkerdoos_houtSW2#State]=0
  GPIO,22,0
 else
  GPIO,22,1
endif
AsyncEvent,checkSwitches
endon


on checkSwitches do
  LogEntry,"checkSwitches: current state: [ST1 Or ST2]"
  if [Stekkerdoos_houtST1#State]=1 Or [Stekkerdoos_houtST2#State]=1
    GPIO,16,1 // Turn on LED
    Else
    //Elseif [Stekkerdoos_houtST1#State]=1 and [Stekkerdoos_houtST2#State]=1
    GPIO,16,0
  endif
Endon  

[chromo23]

So the result of the log is from this script:

so "checkSwitches" is still to early... i recommend you this:

Edit: To be really sure the "checkSwitches" event is fired at the right time you could use a new event block like this:

Code: Select all

On Stekkerdoos_houtST1#State Do
 AsyncEvent,checkSwitches
Endon

And did you find the mistake in your rules?

Dick60 wrote: ↑14 Apr 2023, 08:11
ACT : Endon
Command unknown: Endon
It seems you made some mistake in your rules, cause this shouldn´t happen and is probably the cause, that leads to unexpected behavior....
Can you please post all of your rules? Otherwise it is impossible to analyze this.

[chromo23]

And to shorten the code a bit you could use a "wildcard" in your rules making the "checkSwitches" event obsolete

Code: Select all

On Stekkerdoos_houtST* Do
 LogEntry,"checkSwitches: current state: ST1=[Stekkerdoos_houtST1#State], ST2=[Stekkerdoos_houtST2#State]" // etc.
  If [Stekkerdoos_houtST1#State]=1 or [Stekkerdoos_houtST2#State]=1 // Add more on-state switches like this, using the 'or' condition, when needed
    GPIO,16,0 // Turn on LED
  Else
    GPIO,16,1
  Endif
Endon

[Dick60]

This is working . Now that I know that you can use a wildcard, makes other projects for even more simple, ha ha. Thanks for the support and I finish-up the project.

[chromo23]

Great!

And please double check, that this doesn´t occur anymore:

ACT : Endon
Command unknown: Endon

As i said earlier, this is probably caused by a mistake/typo in your rules.
And such things can lead to serious issues and unwanted behavior when rules are processed!!!

[Dick60]

fixed it already

[Ath]

fixed it already

What was the fix?

[Dick60]

there was a space in front of the command. I thought that it was not that important but that did the job. Strange but now no errors anymore